Daftar isi
Uji validitas butir tidak harus memakai SPSS. Excel dan Google Sheets punya semua fungsi yang dibutuhkan: korelasi Pearson, nilai t kritis, dan nilai p. Halaman ini menjelaskan rumusnya langkah demi langkah.
Konsep validitas dan dasar keputusannya dibahas di uji validitas. Bila hanya butuh hasilnya, tempel data dari Excel ke alat di halaman itu; hasilnya langsung keluar lengkap dengan kalimat untuk Bab 4.
Data contoh
Angket 5 butir, 10 responden (rekaan)
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Resp | P1 | P2 | P3 | P4 | P5 | Total |
| 2 | 1 | 4 | 4 | 3 | 3 | 5 | 19 |
| 3 | 2 | 3 | 3 | 3 | 4 | 4 | 17 |
| 4 | 3 | 5 | 4 | 4 | 3 | 5 | 21 |
| 5 | 4 | 2 | 3 | 2 | 4 | 3 | 14 |
| 6 | 5 | 4 | 5 | 4 | 2 | 4 | 19 |
| 7 | 6 | 3 | 2 | 3 | 3 | 2 | 13 |
| 8 | 7 | 5 | 5 | 4 | 3 | 5 | 22 |
| 9 | 8 | 2 | 2 | 1 | 3 | 2 | 10 |
| 10 | 9 | 4 | 3 | 4 | 4 | 4 | 19 |
| 11 | 10 | 3 | 4 | 3 | 2 | 3 | 15 |
Kolom G diisi dengan =SUM(B2:F2) lalu disalin ke bawah.
Rumus di bawah memakai pemisah titik koma (;) seperti Excel dengan pengaturan Indonesia. Bila Excel-mu memakai titik sebagai tanda desimal, ganti titik koma dengan koma dan 0,05 dengan 0.05.
Langkah 1: r hitung
Di sel B13 ketik:
=PEARSON(B2:B11;$G$2:$G$11)
Tanda $ mengunci kolom total, sehingga rumus bisa disalin ke C13 sampai F13. Hasilnya:
| P1 | P2 | P3 | P4 | P5 | |
|---|---|---|---|---|---|
| r hitung | 0,931 | 0,796 | 0,882 | −0,036 | 0,947 |
Langkah 2: r tabel
r tabel diturunkan dari t tabel dengan df = n − 2. Di sel B14 ketik:
=T.INV.2T(0,05;8)/SQRT(8+T.INV.2T(0,05;8)^2)
Hasilnya 0,632, sama dengan tabel r untuk df 8 pada taraf 5% dua sisi. Supaya otomatis mengikuti jumlah responden, ganti angka 8 dengan COUNT(G2:G11)-2.
Langkah 3: keputusan
Di sel B15 ketik lalu salin ke kanan:
=IF(B13>$B$14;"Valid";"Tidak valid")
Hasilnya: P1, P2, P3, dan P5 valid; P4 tidak valid karena −0,036 jauh di bawah 0,632. Korelasi negatif yang hampir nol seperti ini sering terjadi pada butir yang membingungkan responden, atau pada butir negatif yang lupa dibalik skornya. Periksa dulu kemungkinan kedua sebelum membuang butirnya.
Langkah 4 (opsional): nilai Sig.
Bila pedomanmu meminta nilai Sig. seperti di SPSS, hitung dulu nilai t dari r, lalu nilai p dua sisi. Untuk P1 di sel B16 dan B17:
=B13*SQRT(8)/SQRT(1-B13^2)
=T.DIST.2T(ABS(B16);8)
Untuk P1 hasilnya t = 7,190 dan p = 0,0000934 (Excel mungkin menampilkannya sebagai 9,34E-05). Karena p < 0,05, butir valid. Keputusan ini selalu sama dengan membandingkan r hitung dan r tabel.
Langkah 5 (opsional): korelasi terkoreksi
Korelasi butir-total biasa sedikit menguntungkan butir itu sendiri, karena skornya ikut di dalam total. Korelasi terkoreksi membandingkan butir dengan total tanpa butir itu:
=PEARSON(B2:B11;$G$2:$G$11-B2:B11)
Di Excel 365 dan Google Sheets rumus ini langsung jalan. Di Excel versi lama, akhiri dengan Ctrl+Shift+Enter karena berupa rumus larik. Hasilnya lebih kecil: 0,870; 0,646; 0,796; −0,223; dan 0,895. Keputusannya tetap sama, tetapi P2 kini hanya sedikit di atas r tabel.
Lanjut: reliabilitas dengan Excel
Setelah P4 dibuang, Cronbach's Alpha untuk empat butir yang valid dihitung dari varians setiap butir dan varians total empat butir itu (misalnya di kolom H, =SUM(B2:D2;F2)):
=4/3*(1-SUM(VAR.S(B2:B11);VAR.S(C2:C11);VAR.S(D2:D11);VAR.S(F2:F11))/VAR.S(H2:H11))
Hasilnya 0,926, jauh di atas 0,70, jadi instrumen reliabel. Penjelasan rumusnya ada di uji reliabilitas.
Semua angka di halaman ini rekaan untuk latihan dan sudah dihitung ulang dengan R.
Menuliskannya di Bab 3 atau Bab 4
Uji validitas dilakukan pada 5 butir dengan 10 responden menggunakan korelasi Pearson antara skor butir dan skor total. Pada taraf signifikansi 5% (dua sisi) dan df = 8, r tabel sebesar 0,632. Sebanyak 4 butir dinyatakan valid karena r hitung lebih besar dari r tabel, sedangkan butir P4 tidak valid.
Kesalahan umum
- Kolom total ikut digeser saat rumus disalin, karena lupa tanda $.
- r tabel diambil dengan df = n, padahal yang benar n − 2.
- Memakai uji satu sisi padahal pedomanmu memakai dua sisi. Tabel r yang umum di skripsi adalah dua sisi.
- Butir negatif belum dibalik sebelum skor total dihitung.
- Responden dengan jawaban kosong ikut dihitung. Lengkapi atau keluarkan responden itu dulu.
Pertanyaan umum
Rumus Excel-ku error, padahal sama persis dengan contoh. Kenapa?
Pemisah argumen bergantung pada pengaturan wilayah komputer. Bila tanda desimalnya koma (pengaturan Indonesia), pemisah argumen adalah titik koma: =T.INV.2T(0,05;8). Bila tanda desimalnya titik, pemisahnya koma: =T.INV.2T(0.05,8).
PEARSON atau CORREL?
Hasilnya sama persis. Keduanya menghitung korelasi Pearson; pakai yang mana saja.
Hasil Excel berbeda dengan SPSS?
Biasanya karena SPSS diatur memakai korelasi butir-total terkoreksi (Corrected Item-Total Correlation di analisis reliabilitas), sedangkan Excel memakai korelasi butir-total biasa, atau sebaliknya. Pastikan keduanya memakai jenis korelasi yang sama.